USBデバイス開発

#include <Adafruit_TinyUSB.h>

void setup() {
  // 動作確認用のLED
  pinMode(PA5, OUTPUT);
  // USB有効時、これはUSBシリアルになる
  Serial.begin(115200);
  // Serial1はPA9,PA10ピンに引き出されたシリアルポート
  Serial1.begin(115200);
}

void loop() {
  digitalWrite(PA5, HIGH);
  delay(100);
  digitalWrite(PA5, LOW);
  Serial.println("Hello from USB Serial");
  Serial1.println("Hello from Hardware Serial (PA9, PA10)");
  delay(1000);
}

#include "Adafruit_TinyUSB.h"

#define PIN_SWITCH_1 PA15
#define PIN_SWITCH_2 PB3
#define PIN_SWITCH_3 PB4
#define PIN_SWITCH_4 PB5


// TinyUSBのテンプレートを利用したHIDレポートディスクリプタ
uint8_t const desc_hid_report[] = {
    TUD_HID_REPORT_DESC_KEYBOARD()
};

Adafruit_USBD_HID usb_hid;


void setup() {
  Serial1.begin(115200);
  Serial1.println("Initializing...");
  Serial1.println("USB keyboard sample code with TinyUSB");

  pinMode(PIN_SWITCH_1, INPUT_PULLUP);
  pinMode(PIN_SWITCH_2, INPUT_PULLUP);
  pinMode(PIN_SWITCH_3, INPUT_PULLUP);
  pinMode(PIN_SWITCH_4, INPUT_PULLUP);

  // Setup HID
  usb_hid.setBootProtocol(HID_ITF_PROTOCOL_KEYBOARD);
  usb_hid.setPollInterval(10);
  usb_hid.setReportDescriptor(desc_hid_report, sizeof(desc_hid_report));
  usb_hid.setStringDescriptor("TinyUSB Keyboard");
  // usb_hid.setReportCallback(NULL, hid_report_callback);
  usb_hid.begin();

  Serial1.println("Ready.");
}


void loop() {

  if (!TinyUSBDevice.mounted()) {
    // まだUSB接続されていない場合は処理をスキップ
    return;
  }

  if (!usb_hid.ready()) {
    // 前回のHIDレポートの送信が終わっていない場合は処理をスキップ
    return;
  }

  // HIDレポートディスクリプタでReportIDを指定していた場合は、その番号。無指定ならば 0
  uint8_t hid_report_id = 0;
  // 修飾キーの状態 (Ctrl, Alt, Shift, GUI)
  uint8_t modifiers = 0;
  // 押されているキーのキーコード (Usage ID。最大6キー)
  uint8_t keycodes[6] = { 0 };

  keycodes[0] = digitalRead(PIN_SWITCH_1) == LOW ? HID_KEY_A : 0;
  keycodes[1] = digitalRead(PIN_SWITCH_2) == LOW ? HID_KEY_B : 0;
  keycodes[2] = digitalRead(PIN_SWITCH_3) == LOW ? HID_KEY_C : 0;
  keycodes[3] = digitalRead(PIN_SWITCH_4) == LOW ? HID_KEY_D : 0;

  usb_hid.keyboardReport(hid_report_id, modifiers, keycodes);
}

// void hid_report_callback(uint8_t report_id, hid_report_type_t report_type, uint8_t const* buffer, uint16_t bufsize) {

// }